home *** CD-ROM | disk | FTP | other *** search
/ Aminet 44 / Aminet 44 (2001)(GTI - Schatztruhe)[!][Aug 2001].iso / Aminet / comm / mail / YAM23.lha / YAM2.3 / Rexx / LocateUser.yam < prev    next >
Text File  |  2000-06-19  |  2KB  |  63 lines
  1. /* LocateUser.yam - Shows geographical location of sender               */
  2. /* $VER: LocateUser.yam 1.0 (16.04.00) © 2000 by M.Beck <mbeck@yam.ch>  */
  3. /* Requires YAM 2.1 or later and Aminet:comm/www/Worldmap.lha for       */
  4. /* graphical display                                                    */
  5.  
  6. /* Display location on worldmap? */
  7. UseWorldmap = 1
  8.  
  9. /* Path and filename of the Worldmap executable */
  10. WorldmapPath = 'C:WorldMap'
  11.  
  12. /* Start Worldmap if it's not already running? */
  13. LaunchWorldmap = 1
  14.  
  15.  
  16. OPTIONS RESULTS
  17. OPTIONS FAILAT 30
  18.  
  19. ADDRESS 'YAM'
  20. MailInfo STEM mi.
  21. PARSE VAR mi.From name' <'email'>'
  22. IF email = '' THEN email = mi.From
  23. PARSE VAR email user'@'domain
  24. IF name = '' THEN name = email
  25. IF UseWorldmap = 1 THEN DO
  26.    IF ~SHOW('Ports','WORLD.1') & (LaunchWorldmap = 1) THEN ADDRESS 'COMMAND' 'Run >NIL: 'WorldmapPath
  27.    ADDRESS 'COMMAND' 'SYS:RexxC/WaitForPort WORLD.1'
  28.    IF ~SHOW('Ports','WORLD.1') THEN UseWorldMap = 0
  29. END
  30. IF UseWorldMap = 1 THEN DO
  31.    ADDRESS 'WORLD.1' 'CLEAR'
  32.    ADDRESS 'WORLD.1' 'WRITE Trying to locate 'name'...'
  33. END
  34. 'GetURL "http://netgeo.caida.org/perl/netgeo.cgi?target='domain'&method=getRecord&nonblocking=true" "T:locateuser.tmp"'
  35. IF RC ~= 0 THEN DO
  36.    'Request "Connection to NetGeo server failed!\nMake sure that you are online" "_Okay"'
  37.    EXIT
  38. END
  39. CALL OPEN(IN, 'T:locateuser.tmp','R')
  40. all = READCH(IN, 10000)
  41. CALL CLOSE(IN)
  42. PARSE VAR all dummy'CITY:          'city'<br>' .
  43. PARSE VAR all dummy'COUNTRY:       'country'<br>' .
  44. PARSE VAR all dummy'STATE:         'state'<br>' .
  45. PARSE VAR all dummy'LAT:           'lat'<br>' .
  46. PARSE VAR all dummy'LONG:          'long'<br>' .
  47. IF (city ~= '') | (country ~= '') THEN DO
  48.    IF UseWorldMap = 1 THEN IF (lat ~= '') & (long ~= '') THEN IF lat*long ~= 0 THEN DO
  49.       ADDRESS 'WORLD.1' 'WRITE 'city' ('country')'
  50.       ADDRESS 'WORLD.1' 'DOT 'trunc(long) trunc(lat)
  51.    END
  52.    msg = 'Sender: 'mi.From'\nCity: 'city'\nState: 'state'\nCountry: 'country
  53.    'Request "'msg'" "_Okay"'
  54. END
  55. ELSE DO
  56.    msg = 'Domain 'domain' could not be located'
  57.    IF UseWorldMap = 1 THEN DO
  58.       ADDRESS 'WORLD.1' 'WRITE 'msg
  59.    END
  60.    ELSE 'Request "'msg'" "_Okay"'
  61. END
  62.  
  63.